查看题目 Show Problem

题目:[NOIP2010]关押罪犯

问题编号:600

题目描述

S 城现有两座监狱，一共关押着N 名罪犯，编号分别为1~N。他们之间的关系自然也极不和谐。很多罪犯之间甚至积怨已久，如果客观条件具备则随时可能爆发冲突。我们用“怨气值”（一个正整数值）来表示某两名罪犯之间的仇恨程度，怨气值越大，则这两名罪犯之间的积怨越多。如果两名怨气值为c 的罪犯被关押在同一监狱，他们俩之间会发生摩擦，并造成影响力为c 的冲突事件。
每年年末，警察局会将本年内监狱中的所有冲突事件按影响力从大到小排成一个列表，然后上报到S 城Z 市长那里。公务繁忙的Z 市长只会去看列表中的第一个事件的影响力，如果影响很坏，他就会考虑撤换警察局长。
在详细考察了N 名罪犯间的矛盾关系后，警察局长觉得压力巨大。他准备将罪犯们在两座监狱内重新分配，以求产生的冲突事件影响力都较小，从而保住自己的乌纱帽。假设只要处于同一监狱内的某两个罪犯间有仇恨，那么他们一定会在每年的某个时候发生摩擦。那么，应如何分配罪犯，才能使Z 市长看到的那个冲突事件的影响力最小？这个最小值是多少？

【输入输出样例说明】
罪犯之间的怨气值如下面左图所示，右图所示为罪犯的分配方法，市长看到的冲突事件影响力是3512（由2 号和3 号罪犯引发）。其他任何分法都不会比这个分法更优。

【数据范围】
对于30%的数据有N≤ 15。
对于70%的数据有N≤ 2000，M≤ 50000。
对于100%的数据有N≤ 20000，M≤ 100000。

输入格式

输入文件的每行中两个数之间用一个空格隔开。
第一行为两个正整数N 和M，分别表示罪犯的数目以及存在仇恨的罪犯对数。
接下来的M 行每行为三个正整数aj，bj，cj，表示aj 号和bj 号罪犯之间存在仇恨，其怨
气值为cj。数据保证1<aj=<=bj<=N ，0 < cj≤ 1,000,000,000，且每对罪犯组合只出现一
次。

输出格式

共1 行，为Z 市长看到的那个冲突事件的影响力。如果本年内监狱中未发生任何冲突事件，请输出0。

样例输入

4 6
1 4 2534
2 3 3512
1 2 28351
1 3 6618
2 4 1805
3 4 12884

样例输出

3512

这题的关键在于如何建带路径的并查集(即Path集）

d[x]表示x到它父亲的距离

先存下它的父亲q_father,最后维护距离d[x]=d[q_father]+d[x]

合并时先将它们的父节点改为根结点i,j，则father[i]=j; d[i]=d[x]+d[y]+dis_x_y

Program prison;
type
   edge2=record
           u,v,w:longint;
         end;
const
   maxn=20000;
   maxm=100000;
var
   n,m,i,j:longint;
   father,d:array[1..maxn]of longint;
   edge:array[1..maxm] of edge2;
procedure swap(var a,b:edge2);
var
   t:edge2;
begin
   t:=a;a:=b;b:=t;
end;
procedure qsort(l,r:longint);
var
   i,j,m:longint;
begin
   i:=l;
   j:=r;
   m:=edge[(l+r) div 2].w;
   repeat
      while (edge[i].w>m) do inc(i);
      while (edge[j].w<m) do dec(j);
      if i<=j then
      begin
         swap(edge[i],edge[j]);
         inc(i);dec(j);
      end;
   until i>j;
   if (l<j) then qsort(l,j);
   if (i<r) then qsort(i,r);
end;
function getfather(x:longint):longint;
var
   q_father:longint;
begin
   if (father[x]=x) then exit(x);
   q_father:=father[x];
   father[x]:=getfather(father[x]);
   d[x]:=(d[q_father]+d[x]);
   exit(father[x]);
end;
procedure union(x,y:longint);
var
   i,j,dis:longint;
begin
   i:=getfather(x);
   j:=getfather(y);
   dis:=d[x]+d[y]+1;

   father[i]:=j;
   d[i]:=dis;
end;
begin
   read(n,m);
   for i:=1 to n do father[i]:=i;
   fillchar(d,sizeof(d),0);
   for i:=1 to m do read(edge[i].u,edge[i].v,edge[i].w);
   qsort(1,m);

   for i:=1 to m do
   begin
      if (getfather(edge[i].u)<>getfather(edge[i].v)) then union(edge[i].u,edge[i].v)
      else
      if ((d[edge[i].u]+d[edge[i].v]) mod 2=0) then
      begin
         writeln(edge[i].w);
         halt;
      end;
   end;
   writeln('0');
end.

求森林数，裸的并查集

Program c;
var
   n,i,j,ans:longint;
   map:array[1..100,1..2] of longint;
   f:array[1..100] of longint;
function getfather(a:longint):longint;
begin
   if f[a]=a then exit(a);
   f[a]:=getfather(f[a]);
   exit(f[a]);
end;
procedure union(a,b:longint);
begin
   f[getfather(a)]:=f[getfather(b)];
end;
begin
   read(n);
   for i:=1 to n do
   begin
      f[i]:=i;
      read(map[i,1],map[i,2]);
      for j:=1 to i-1 do
         if (map[i,1]=map[j,1]) or (map[i,2]=map[j,2]) then
            union(i,j);

   end;
   ans:=0;
   for i:=2 to n do
      if getfather(i)<>getfather(i-1) then
      begin
         inc(ans);
         union(i,i-1);
      end;
   writeln(ans);

end.

唯一的WA

是把0的父亲当成祖先

father[x]和getfather(x)差别巨大啊

Program p1611;
const
   maxn=30010;
   maxm=500;
var
   n,m,i,j,k,p1,p2,ans,f0:longint;
   father:array[0..maxn] of longint;
function getfather(x:longint):longint;
begin
   if father[x]=x then exit(x);
   father[x]:=getfather(father[x]);
   exit(father[x]);
end;
procedure union(x,y:longint);
begin
   if getfather(x)<>getfather(y) then
      father[father[x]]:=father[father[y]];
end;
begin
   read(n,m);
   while (n+m>0) do
   begin
      for i:=0 to n-1 do father[i]:=i;
      for i:=1 to m do
      begin
         read(k);
         if k>0 then read(p1);
         if k>1 then
            for j:=2 to k do
            begin
               read(p2);
               union(p1,p2);
            end;
      end;
      ans:=1;
      f0:=getfather(0);
      for i:=1 to n-1 do if getfather(i)=f0 then inc(ans);
      writeln(ans);
      read(n,m);
   end;
end.

这题的思路就是找一个范围，看看这个范围是否可行

主流是二分Ans，我是先把点排序，求最小生成树检查首位的

Program P2110;
type
   ed=record
      u,v,w:longint;
      end;
var
   a:array[1..120,1..120] of longint;
   edge:array[0..30000] of ed;
   n,i,j,size,ans:longint;
   now:longint;
   father:array[0..10001] of longint;
   b:array[0..121,0..121] of boolean;
procedure add(u,v,w:longint);
begin
   inc(size);
   edge[size].u:=u;
   edge[size].v:=v;
   edge[size].w:=w;

end;
procedure qsort(l,r:longint);
var
   i,j,m:longint;
   p:ed;
begin
   i:=l;
   j:=r;
   m:=edge[(l+r) shr 1].w;
   repeat
      while edge[i].w<m do inc(i);
      while edge[j].w>m do dec(j);
      if i<=j then
      begin
         p:=edge[i];
         edge[i]:=edge[j];
         edge[j]:=p;
         inc(i);
         dec(j);
      end;
   until i>j;
   if l<j then qsort(l,j);
   if i<r then qsort(i,r);



end;
function getfather(x:longint):longint;
begin
   if x=father[x] then exit(x);
   father[x]:=getfather(father[x]);
   exit(father[x]);
end;
function hash(x,y:longint):longint;
begin
  exit((x-1)*n+y);
end;
begin
   size:=0;
   read(n);
   for i:=1 to n do
      for j:=1 to n do
      begin
         read(a[i,j]);
         add(i,j,a[i,j]);
      end;

  // (0,n*n)
   qsort(1,size);


   edge[0].w:=edge[1].w-1;
   ans:=110;
   //                 writeln;
   for i:=1 to size do
   begin

      if edge[i].w=edge[i-1].w then continue;
      for j:=0 to n*n do father[j]:=j;
      fillchar(b,sizeof(b),false);
      for j:=i to size do
      begin
         b[edge[j].u,edge[j].v]:=true;
         now:=hash(edge[j].u,edge[j].v);

         if b[edge[j].u-1,edge[j].v] then
            if getfather(now)<>getfather(now-n) then
            begin
               father[father[now]]:=father[father[now-n]];
               if getfather(0)=getfather(n*n) then break;
            end;

         if b[edge[j].u+1,edge[j].v] then
            if getfather(now)<>getfather(now+n) then
            begin
               father[father[now]]:=father[father[now+n]];
               if getfather(0)=getfather(n*n) then break;
            end;

         if b[edge[j].u,edge[j].v+1] then
            if getfather(now)<>getfather(now+1) then
            begin
               father[father[now]]:=father[father[now+1]];
               if getfather(0)=getfather(n*n) then break;
            end;

         if b[edge[j].u,edge[j].v-1] then
            if getfather(now)<>getfather(now-1) then
            begin
               father[father[now]]:=father[father[now-1]];
               if getfather(0)=getfather(n*n) then break;
            end;



         if getfather(1)=getfather(n*n) then break;

      end;



      if getfather(1)<>getfather(n*n) then break;
      if ans>edge[j].w-edge[i].w then ans:=edge[j].w-edge[i].w;


   end;
   writeln(ans);



end.