查看题目 Show Problem

题目:[NOIP2010]引水入城

问题编号:601

题目描述

在一个遥远的国度，一侧是风景秀美的湖泊，另一侧则是漫无边际的沙漠。该国的行政区划十分特殊，刚好构成一个N 行M 列的矩形，如上图所示，其中每个格子都代表一座城市，每座城市都有一个海拔高度。
为了使居民们都尽可能饮用到清澈的湖水，现在要在某些城市建造水利设施。水利设施有两种，分别为蓄水厂和输水站。蓄水厂的功能是利用水泵将湖泊中的水抽取到所在城市的蓄水池中。因此，只有与湖泊毗邻的第1 行的城市可以建造蓄水厂。而输水站的功能则是通过输水管线利用高度落差，将湖水从高处向低处输送。故一座城市能建造输水站的前提，是存在比它海拔更高且拥有公共边的相邻城市，已经建有水利设施。
由于第N 行的城市靠近沙漠，是该国的干旱区，所以要求其中的每座城市都建有水利设施。那么，这个要求能否满足呢？如果能，请计算最少建造几个蓄水厂；如果不能，求干旱区中不可能建有水利设施的城市数目。

【样例1 说明】
只需要在海拔为9 的那座城市中建造蓄水厂，即可满足要求。
【样例2 说明】

上图中，在3 个粗线框出的城市中建造蓄水厂，可以满足要求。以这3 个蓄水厂为源头
在干旱区中建造的输水站分别用3 种颜色标出。当然，建造方法可能不唯一。

【数据范围】

输入格式

输入文件的每行中两个数之间用一个空格隔开。
输入的第一行是两个正整数N 和M，表示矩形的规模。
接下来N 行，每行M 个正整数，依次代表每座城市的海拔高度。

输出格式

输出有两行。如果能满足要求，输出的第一行是整数1，第二行是一个整数，代表最少
建造几个蓄水厂；如果不能满足要求，输出的第一行是整数0，第二行是一个整数，代表有
几座干旱区中的城市不可能建有水利设施。

样例输入

【输入输出样例1】
2 5
9 1 5 4 3
8 7 6 1 2

【输入输出样例2】
3 6
8 4 5 6 4 4
7 3 4 3 3 3
3 2 2 1 1 2

样例输出

【输入输出样例1】
1
1

【输入输出样例2】
1
3

先floodfill，判定有无解。

若有解，则没个蓄水站必然会覆盖的区间一定连续

下面这幅图说明了这一点:

显然水无论如何也无法流进中间的区间，证毕。

注：下文使用的区间覆盖假定一定有解，若无解则需另加考虑。

Another PS:http://lhz1208.diandian.com/post/2011-11-11/6674864

Program desert;
const
   maxn=501;
   maxm=501;
   INF=2139062143;
var
   n,m,i,j,tot,nowl,maxr:longint;
   height:array[0..maxn,0..maxm] of longint;
   l,r:array[1..maxm] of longint;

   b:array[0..maxn,0..maxm] of boolean;
Procedure swap(var a,b:longint);
var
   p:longint;
begin
   p:=a;a:=b;b:=p;
end;
function max(a,b:longint):longint;
begin
   if a<b then exit(b) else exit(a);
end;
Procedure floodfill(x,y:longint);
var
   i,j:longint;
begin
   b[x,y]:=true;
   if not(b[x+1,y]) and (height[x+1,y]<height[x,y]) then floodfill(x+1,y);
   if not(b[x-1,y]) and (height[x-1,y]<height[x,y]) then floodfill(x-1,y);
   if not(b[x,y+1]) and (height[x,y+1]<height[x,y]) then floodfill(x,y+1);
   if not(b[x,y-1]) and (height[x,y-1]<height[x,y]) then floodfill(x,y-1);
end;
Procedure qsort(_l,_r:longint);
var
   i,j,m,p:longint;
begin
   i:=_l;
   j:=_r;
   m:=l[(i+j) div 2];
   repeat
      while (l[i]<m) do inc(i);
      while (l[j]>m) do dec(j);
      if i<=j then
      begin
         swap(l[i],l[j]);
         swap(r[i],r[j]);
         inc(i); dec(j);
      end;
   until i>j;
   if (_l<j) then qsort(_l,j);
   if (i<_r) then qsort(i,_r);
end;
begin
   read(n,m);
   fillchar(b,sizeof(b),false);
   fillchar(height,sizeof(height),127);
   for i:=1 to n do
      for j:=1 to m do
         read(height[i,j]);

   tot:=0;
   for i:=1 to m do floodfill(1,i);

   for i:=1 to m do if not(b[n,i]) then inc(tot);
   if tot>0 then
   begin
      writeln('0');
      writeln(tot);
      halt;
   end;

   for i:=1 to m do
   begin
      fillchar(b,sizeof(b),false);
      floodfill(1,i);
      l[i]:=1;
      r[i]:=m;
      while not(b[n,l[i]]) and (l[i]<m) do inc(l[i]);
      while not(b[n,r[i]]) and (r[i]>1) do dec(r[i]);
      if not(b[n,l[i]]) then begin l[i]:=0; r[i]:=0; end;
   end;
   qsort(1,m);


   nowl:=1; tot:=0; maxr:=0;
   for i:=1 to m do
   begin
      if (l[i]<=nowl) then maxr:=max(maxr,r[i])
      else
      begin
         inc(tot);
         nowl:=maxr+1;
         maxr:=r[i];
      end;
   end;
   if nowl<m+1 then inc(tot);
   writeln('1');
   writeln(tot);





end.